diff --git a/default.nix b/default.nix
index 3b4f9f2..811e4f2 100644
--- a/default.nix
+++ b/default.nix
@@ -19,6 +19,8 @@ let
     pkgs = pkgs;
   };
   cetcd = callPackage ./pkgs/c/cetcd/package.nix {};
+  deepseek-tui = callPackage ./pkgs/d/deepseek-tui/package.nix {};
+  kiro-account-manager = callPackage ./pkgs/k/kiro-account-manager/package.nix {};
 in
 {
   xbuild = xbuild;
@@ -29,4 +31,6 @@ in
   unity_test_with_color = unity_test_with_color;
   uem = uem;
   cetcd = cetcd;
+  deepseek-tui = deepseek-tui;
+  kiro-account-manager = kiro-account-manager;
 }
diff --git a/pkgs/d/deepseek-tui/package.nix b/pkgs/d/deepseek-tui/package.nix
new file mode 100644
index 0000000..f87781f
--- /dev/null
+++ b/pkgs/d/deepseek-tui/package.nix
@@ -0,0 +1,34 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  dbus,
+  openssl,
+}:
+
+rustPlatform.buildRustPackage {
+  pname = "deepseek-tui";
+  version = "0.8.20";
+
+  src = fetchFromGitHub {
+    owner = "shen390s";
+    repo = "DeepSeek-TUI";
+    rev = "f183501fbd2199d9d10040e1a63392de604f172c";
+    hash = "sha256-E621hEtWjdr5c9MZsifaYgdjyFvXcMvKLFmiyC4+Hr8=";
+  };
+
+  cargoHash = "sha256-7Atb+VhGHk1RtNJl+7kJOimpc/4sZs/pTKDRWmUzoSI=";
+
+  doCheck = false;
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ dbus openssl ];
+
+  meta = {
+    description = "A TUI client for DeepSeek AI";
+    homepage = "https://github.com/shen390s/DeepSeek-TUI";
+    license = lib.licenses.mit;
+    mainProgram = "deepseek";
+  };
+}
diff --git a/pkgs/k/kiro-account-manager/package.nix b/pkgs/k/kiro-account-manager/package.nix
new file mode 100644
index 0000000..6e8926d
--- /dev/null
+++ b/pkgs/k/kiro-account-manager/package.nix
@@ -0,0 +1,71 @@
+{ lib
+, rustPlatform
+, fetchFromGitHub
+, buildNpmPackage
+, pkg-config
+, openssl
+, glib
+, gtk3
+, libsoup_3
+, webkitgtk_4_1
+, dbus
+, libayatana-appindicator
+}:
+
+let
+  pname = "kiro-account-manager";
+  version = "1.8.5";
+
+  src = fetchFromGitHub {
+    owner = "hj01857655";
+    repo = "kiro-account-manager";
+    rev = "2e2d4b09d3ad3b028dab719958707d9e19923261";
+    hash = "";
+  };
+
+  frontend = buildNpmPackage {
+    pname = "${pname}-frontend";
+    inherit version src;
+
+    npmDepsHash = "";
+
+    installPhase = ''
+      runHook preInstall
+      cp -r dist $out
+      runHook postInstall
+    '';
+  };
+
+in rustPlatform.buildRustPackage {
+  inherit pname version src;
+
+  sourceRoot = "${src.name}/src-tauri";
+
+  cargoHash = "";
+
+  preBuild = ''
+    cp -r ${frontend} ../dist
+  '';
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    openssl
+    glib
+    gtk3
+    dbus
+    libsoup_3
+    webkitgtk_4_1
+    libayatana-appindicator
+  ];
+
+  doCheck = false;
+
+  meta = {
+    description = "Kiro IDE account manager with multi-account switching and quota monitoring";
+    homepage = "https://github.com/hj01857655/kiro-account-manager";
+    license = lib.licenses.cc-by-nc-sa-40;
+    mainProgram = "kiro-account-manager";
+    platforms = lib.platforms.linux;
+  };
+}